NSIS Wiki - User contributions [en]

Talk:FontName plug-in

2017-02-26T14:49:28Z

Dsuess: Update to base installer

Do you plan on updating the FontName plugin to include the latest changes from [[Advanced Font Installation]]? We've been having to manually execute the FontName plugin and then copy over the patched files to fix the issues when creating a new installation environment. Keep up the great work!

NSIS Dialog Designer

2017-01-17T15:33:08Z

Dsuess: /* Version history */ Added notes for v1.4.2

[[Category:Related_Software]]
NSIS Dialog Designer is an IDE that provides a graphical tool to easily design your custom setup pages for the great NSIS installer system.

It supports MUI2 (Modern User Interface 2) dialogs and generates NSIS files ready to be included into your own *.nsi install script.

[[File:ndd_screenshot.png|thumb|Screenshot]]

NSIS Dialog Designer is '''freeware''' and can be used to design both free and commercial setups.

NSIS Dialog Designer is still a work-in-progress; please test it and give me your feedback to let this tool suit your needs.

Use this thread for comments:
http://forums.winamp.com/showthread.php?p=2764874#post2764874.

== How does it work ==
NSIS Dialog Designer is a relatively simple IDE; if you're used to Visual Studio(TM) or Eclipse you'll feel at home.
Start by creating a new dialog (File | New), then add some controls to it by choosing them from the Toolbox.
Each control has properties and you can easily edit them into the property grid.

When you save the dialog (suppose you called it Form1), NSIS Dialog Designer will create 2 separate files:

*'''Form1.nsddef''' is the definition of your dialog in XML format; it contains all controls definitions and their properties
*'''Form1.nsdinc''' is an NSIS script containing all the NSIS commands needed to render your dialog; this is the file you'll include into your own NSIS setup script.

== Supported controls ==
NSIS Dialog Designer actually supports the following controls:
*HLine
*VLine
*Label
*Icon
*Bitmap
*Link
*Button
*GroupBox
*CheckBox
*RadioButton
*Text
*Password
*Number
*ComboBox
*DropList
*ListBox
*ProgressBar
*DirRequest
*FileRequest
*RichEdit

For each control you can set name, position and size, font, colors.
Controls also have events bindable to your own script functions.

You can also provide your own script parts and fully customize the generated script.

== Download ==
NSIS Dialog Designer is free and available here:
* http://coolsoft.altervista.org/en/nsisdialogdesigner

== Version history ==
<pre>
v.1.4.2 - 2016-08-24
FIX: Fixed setup procedure for Windows 10 compatibility.
FIX: Fixed .NET framework detection (use .NET Framework 4.0 if already installed).

v.1.4.1 - 2015-09-07
FIX: Fixed small memory leak in generated NSIS script
(dialog handle left on the stack when calling nsDialogs::Show).

v.1.4.0 - 2015-03-17
NEW: Dialog has a new property "DialogUI" which allows user to set custom
DialogID and Size (i.e.: using a different UI like sdbarker_tiny.exe)
FIX: HLine and VLine controls don't pop their handle from stack.

v.1.3.3 - 2015-03-09
FIX: Readonly and TextLimit properties of Number control do not work.

v.1.3.2 - 2014-11-10
FIX: Fixed DialogID and Size management, form Size is now readonly unless DialogID is set to a custom value.

v.1.3.1 - 2014-10-27
FIX: Can't set custom dialog size, it always revert back to default.
FIX: Style and ExStyle dialog properties were serialized even of not necessary.
FIX: Removed useless Visible and Enabled dialog properties.

v.1.3.0 - 2014-08-12
NEW: TabIndex property of each control is now synchronized with control order into its parent child controls collection.
Changing TabIndex (directly or through the "Set TabOrder..." menu command will also change the scripting order of the
control into the generated NSIS script.
NEW: A warning is now emitted into .nsdinc file to warn the user about manually editing the file.
FIX: When dragging a control over another, the dragged control disappeared making it difficult to place two overlapping
controls (think about a background bitmap).
FIX: Show a custom error message when setting Dialog BackColor property to Transparent.
FIX: Fixed properties exposed by HLine and VLine special controls.
FIX: Generated script for DirRequest/FileRequest controls is missing some properties (Enabled, Visible, onChange, onClick,
Style, ExStyle, ControlCustomScript).

v.1.2.0 - 2014-07-11
NEW: CoordinateSystem conversions are now done with higher precision.
(thanks to shadowpoa for feedback: http://forums.winamp.com/showpost.php?p=3001224)
NEW: Control sizes are now written with up to 2 decimals in NSIS generated script.
NEW: Added a new "All" subproperty to controls CoordinateSystem property;
it can be used to change X,Y,Width,Height subproperties all together.
FIX: Wrong vertical CoordinateSystem conversion "Pixel --> DialogUnits".

v.1.1.3 - 2013-12-16
FIX: Fixed generated script for DirRequest and FileRequest controls, not respecting CoordinateSystem.

v.1.1.2 - 2013-01-11
FIX: Removed non-working color properties on ComboBox, CheckBox and RadioButton.
See here for workarounds:
ComboBox: http://forums.winamp.com/showpost.php?p=2174815
CheckBox: http://forums.winamp.com/showpost.php?p=2354612
RadioButton: http://forums.winamp.com/showpost.php?p=1974758
FIX: Multiline TextBox coordinates were always in pixels
FIX: TextBox creation script styles when Multiline=True

v.1.1.1 - 2012-10-01
FIX: Fixed generated script for FileRequest control (wrong test on returned string).

v.1.1.0 - 2012-09-14
NEW: Improved support for DialogIDs other than the default one (1018).
User can now select 1044 (Welcome & Finish pages) and designer will change dialog size accordingly.
NEW: Added RichText control support. It does not support RTF text loading, it must be customized by
the user (see here: http://forums.winamp.com/showthread.php?t=288129)

v.1.0.0 - 2012-08-25
After a long time from latest one, it's now time to release the first stable version.
FIX: Text property of Number control now accepts numeric values and variable nalems (like $abc).
FIX: Minor cosmetic fixes.

v.0.9.16 - 2012-04-20
FIX: SelectedItem property of ListBox, ComboBox and DropList controls now accepts any value (like $abc).

v.0.9.15 - 2012-04-13
FIX: NullReference exception thrown when adding an HLine or VLine control.

v.0.9.14 - 2012-03-20
NEW: Panel control, which is only a container for other controls
(useful to create more than one RadioButtons group).
It has no corresponding NSIS control, so no NSIS script if generated for it.
NEW: Added property "Checked" to RadioButton control.
Only one RadioButton can be selected at once; if you need to create two (or more) different groups,
you must include RadioButtons into a GroupBox or Panel control.

v.0.9.13 - 2012-03-09
FIX: Wrong code generated for MaxLength property of TextBox control (thanks to fabpolli for bug report).

v.0.9.12 - 2012-02-27
NEW: Added "Percentage" to the available NSIS coordinate systems.
NEW: Selection of NSIS coordinate system is now possible at control level, and for each
component (X, Y, Width, Height). So now is possible to have different coordinate
systems for different controls.
Controls coordinate system default value is "Inherit"; this means that by default
each control is rendered using the same coordinate system as the containing dialog.

v.0.9.11 - 2012-02-11
NEW: NSIS scripts (*.nsdinc files) controls position and size values can now be selected
between DU (Dialog units, the new default mode) and Pixels.
The default coordinate system mode can be set into Options dialog.
NEW: Added 2 new controls: DirRequest and FileRequest.

v.0.9.10 - 2011-11-23
FIX: Fixed bug that prevents opening forms where SetupType property is different from default value (Install).
FIX: IDE layout was not saved correctly and lost between version upgrades.
Please reset layout (View | Reset layout), customize it then restart IDE to save correctly.

v.0.9.9 - 2011-11-21
NEW: Added new "check updates" features: it periodically checks for new releases on CoolSoft website.
NEW: Script preview editor now preserves selection and cursor position after script changes and
when switching between multiple opened dialogs.
NEW: TabIndex property can now be used to customize focus path through controls.
NEW: Added context menu to dialog designer, it shows Edit menu items.
NEW: Dialog .nsddef files are now created with UTF-8 encoding.
NEW: .nsddef and .nsdinc files now include NSISDialogDesigner version into header comments.
NEW: Duplicate font definitions are merged, generating only a single variable.
NEW: .nsddef files can now be opened by drag&drop from Windows Explorer.
NEW: IDE layout can now be reset through View menu item "Reset layout".
FIX: Property are now stored into .nsddef only if value is different from default.
FIX: Fixed issue on copy/paste controls (duplicate control name).
FIX: User custom scripts won't be generated during debug, avoiding compile error due to missing functions.

v.0.9.8 - 2011-09-12
NEW: Script editor/preview now has NSIS syntax highlighting and code folding,
thanks to FastColoredTextBox
(LGPL3 control, see here: http://www.codeproject.com/KB/edit/FastColoredTextBox_.aspx)
FIX: Styles property wrongly uses the value of ExStyles property.

v.0.9.7 - 2011-09-11
NEW: Added support for Unicode into generated .nsdinc scripts (needs an Unicode version of NSIS).
NEW: New (self explaining) control properties: Visible and Enabled.
NEW: Dialog name (and so the corresponding NSIS variable) can now be set independently
from its .nsddef filename. It could be set through the new "Name" dialog property.
FIX: Generated test script (the one compiled with F5) now checks user
custom scripts to avoid redefining an already defined function.
(thanks to Benjamin Richardson for reporting bug)
FIX: Fixed broken uninstall test script.
FIX: Some properties appear in bold into Property Grid, even if their
value is the default one. This caused the generate script to be longer than required.
FIX: Custom script editor now accepts TAB key.
FIX: Script preview is cleared when closing the last dialog editor.
FIX: Fixed focus management issues that prevents DEL key to work into PropertyGrid.

v.0.9.6 - 2011-06-28
NEW: Added new property SetupType to dialog, allowing the generated script to be used
in both Install and Uninstall scripts.
NEW: Debugger code to debug Uninstaller dialogs.
FIX: Cleaned up the debug scripts.

v.0.9.5 - 2011-06-16
BUG: Fixed key management preventing DEL key to be used inside PropertyGrid (thanks to Jovet for bug report)
NEW: Edit menu items now are enabled according to active content (designer, property, toolbox, ...)
NEW: DialogID and Size now are public properties (deedsmedia request)
(can be reset to default values by right-clicking on PropertyGrid item)

v.0.9.4 - 2011-05-29
BUG: Fixed permission issues on UAC enabled systems.

v.0.9.3 - 2011-04-20
NEW: Added new properties ForeColor and BackColor
(not working for: Button, ComboBox, DropList, GroupBox, HLine, VLine, ProgressBar)
NEW: Added new property Font
NEW: Designer now can show a grid (see Tools | Options menu)
BUG: Editor does not save dialogs when exiting with close button.
BUG: Script preview not updated when a new control is added

v.0.9.2 - 2011-04-20
BUG: Missing property "Name" is now shown
(Dialog does not have it because name is the same as its definition filename)

v.0.9.1 - 2011-04-20
NEW: New dockable content with realtime NSIS generated script preview

v.0.9.0 - 2011-04-18
First public release
</pre>

User:Dsuess

2016-05-30T18:26:04Z

Dsuess: initial signiture

-c0de munkey-

Reference/!define

2016-05-30T18:13:51Z

Dsuess: Added StrFTime Format a time string rules

=!define =

[/ifndef | /redef] ([/date|/utcdate] gflag [value]) | (/math gflag val1 OP val2) | (/file gflag filename.txt)

This command will add gflag to the global define list. This will have a similar effect as using the /D switch on the command line (the define only becomes effective after the !define command).

If /date or /utcdate are used, value will be passed into strftime and the result will be used as the value of gflag. strftime converts special symbols into certain parts of the current time or date. For example, %H will be converted into the current hour in 24-hour format. For a complete list of available symbols, search for strftime on MSDN. On POSIX, you can get the list by using man strftime.

If /math is used, the result of 'val1 OP val2', where OP may be +,-,*,&,|,^,/ or % , will be used as the value of gflag. Note that val1 AND val2 MUST be integer values!

If /file is used, the entire text file specified (including whitespace and newlines) will be read and stuffed into gflag.

<highlight-nsis>!define USE_SOMETHING
!define VERSION 1.2
!define /date NOW "%H:%M:%S %d %b, %Y"
!define /math RESULT 3 + 10
!define /math REST 15 % ${RESULT}
!define /file BUNCHASTUFF somesourcefile.cpp
!define /redef USE_SOMETHING ${RESULT} ;redefine USE_SOMETHING</highlight-nsis>

== strftime Format ==
Format a time string as per, [https://msdn.microsoft.com/en-us/library/fe06s4ak.aspx MSDN strftime] rules.

<pre>
Code Description

%A Full weekday name
%b Abbreviated month name
%B Full month name
%c Date and time representation appropriate for locale
%d Day of month as decimal number (01 – 31)
%H Hour in 24-hour format (00 – 23)
%I Hour in 12-hour format (01 – 12)
%j Day of year as decimal number (001 – 366)
%m Month as decimal number (01 – 12)
%M Minute as decimal number (00 – 59)
%p Current locale's A.M./P.M. indicator for 12-hour clock
%S Second as decimal number (00 – 59)
%U Week of year as decimal number, with Sunday as first day of week (00 – 53)
%w Weekday as decimal number (0 – 6; Sunday is 0)
%W Week of year as decimal number, with Monday as first day of week (00 – 53)
%x Date representation for current locale
%X Time representation for current locale
%y Year without century, as decimal number (00 – 99)
%Y Year with century, as decimal number
%z, %Z
Either the time-zone name or time zone abbreviation, depending
on registry settings; no characters if time zone is unknown
%% Percent sign
</pre>

Talk:Check if dir is empty

2016-05-29T23:16:10Z

Dsuess: /* Change suggestion for ALL files */ new section

This function worked great and really helped me out. Thank you very much!

== Change suggestion for ALL files ==

On line 5 of the script, <code>FindFirst $0 $1 "$0\*.*"</code> doesn't actually find ALL files. What if the file is called, "README", then it would not be found.

'''Suggestion:'''
* New: <code>FindFirst $0 $1 "$0\*"</code>
* Old: <code>FindFirst $0 $1 "$0\*.*"</code>

NSIS Dialog Designer

2014-01-23T14:26:30Z

Dsuess: /* Download */ fixed link to take you directly to page (old link was broken)

[[Category:Related_Software]]
NSIS Dialog Designer is an IDE that provides a graphical tool to easily design your custom setup pages for the great NSIS installer system.

It supports MUI2 (Modern User Interface 2) dialogs and generates NSIS files ready to be included into your own *.nsi install script.

[[File:ndd_screenshot.png|thumb|Screenshot]]

NSIS Dialog Designer is still a work-in-progress; please test it and give me your feedback to let this tool suit your needs.

Use this thread for comments:
http://forums.winamp.com/showthread.php?p=2764874#post2764874.

== How does it work ==
NSIS Dialog Designer is a relatively simple IDE; if you're used to Visual Studio(TM) or Eclipse you'll feel at home.
Start by creating a new dialog (File | New), then add some controls to it by choosing them from the Toolbox.
Each control has properties and you can easily edit them into the property grid.

When you save the dialog (suppose you called it Form1), NSIS Dialog Designer will create 2 separate files:

*'''Form1.nsddef''' is the definition of your dialog in XML format; it contains all controls definitions and their properties
*'''Form1.nsdinc''' is an NSIS script containing all the NSIS commands needed to render your dialog; this is the file you'll include into your own NSIS setup script.

== Supported controls ==
NSIS Dialog Designer actually supports the following controls:
*HLine
*VLine
*Label
*Icon
*Bitmap
*Link
*Button
*GroupBox
*CheckBox
*RadioButton
*Text
*Password
*Number
*ComboBox
*DropList
*ListBox
*ProgressBar
*DirRequest
*FileRequest
*RichEdit

For each control you can set name, position and size, font, colors.
Controls also have events bindable to your own script functions.

You can also provide your own script parts and fully customize the generated script.

== Download ==
NSIS Dialog Designer is free and available here:
* http://coolsoft.altervista.org/en/nsisdialogdesigner

== Version history ==
<pre>
v.1.1.3 - 2013-12-16
FIX: Fixed generated script for DirRequest and FileRequest controls, not respecting CoordinateSystem.

v.1.1.2 - 2013-01-11
FIX: Removed non-working color properties on ComboBox, CheckBox and RadioButton.
See here for workarounds:
ComboBox: http://forums.winamp.com/showpost.php?p=2174815
CheckBox: http://forums.winamp.com/showpost.php?p=2354612
RadioButton: http://forums.winamp.com/showpost.php?p=1974758
FIX: Multiline TextBox coordinates were always in pixels
FIX: TextBox creation script styles when Multiline=True

v.1.1.1 - 2012-10-01
FIX: Fixed generated script for FileRequest control (wrong test on returned string).

v.1.1.0 - 2012-09-14
NEW: Improved support for DialogIDs other than the default one (1018).
User can now select 1044 (Welcome & Finish pages) and designer will change dialog size accordingly.
NEW: Added RichText control support. It does not support RTF text loading, it must be customized by
the user (see here: http://forums.winamp.com/showthread.php?t=288129)

v.1.0.0 - 2012-08-25
After a long time from latest one, it's now time to release the first stable version.
FIX: Text property of Number control now accepts numeric values and variable nalems (like $abc).
FIX: Minor cosmetic fixes.

v.0.9.16 - 2012-04-20
FIX: SelectedItem property of ListBox, ComboBox and DropList controls now accepts any value (like $abc).

v.0.9.15 - 2012-04-13
FIX: NullReference exception thrown when adding an HLine or VLine control.

v.0.9.14 - 2012-03-20
NEW: Panel control, which is only a container for other controls
(useful to create more than one RadioButtons group).
It has no corresponding NSIS control, so no NSIS script if generated for it.
NEW: Added property "Checked" to RadioButton control.
Only one RadioButton can be selected at once; if you need to create two (or more) different groups,
you must include RadioButtons into a GroupBox or Panel control.

v.0.9.13 - 2012-03-09
FIX: Wrong code generated for MaxLength property of TextBox control (thanks to fabpolli for bug report).

v.0.9.12 - 2012-02-27
NEW: Added "Percentage" to the available NSIS coordinate systems.
NEW: Selection of NSIS coordinate system is now possible at control level, and for each
component (X, Y, Width, Height). So now is possible to have different coordinate
systems for different controls.
Controls coordinate system default value is "Inherit"; this means that by default
each control is rendered using the same coordinate system as the containing dialog.

v.0.9.11 - 2012-02-11
NEW: NSIS scripts (*.nsdinc files) controls position and size values can now be selected
between DU (Dialog units, the new default mode) and Pixels.
The default coordinate system mode can be set into Options dialog.
NEW: Added 2 new controls: DirRequest and FileRequest.

v.0.9.10 - 2011-11-23
FIX: Fixed bug that prevents opening forms where SetupType property is different from default value (Install).
FIX: IDE layout was not saved correctly and lost between version upgrades.
Please reset layout (View | Reset layout), customize it then restart IDE to save correctly.

v.0.9.9 - 2011-11-21
NEW: Added new "check updates" features: it periodically checks for new releases on CoolSoft website.
NEW: Script preview editor now preserves selection and cursor position after script changes and
when switching between multiple opened dialogs.
NEW: TabIndex property can now be used to customize focus path through controls.
NEW: Added context menu to dialog designer, it shows Edit menu items.
NEW: Dialog .nsddef files are now created with UTF-8 encoding.
NEW: .nsddef and .nsdinc files now include NSISDialogDesigner version into header comments.
NEW: Duplicate font definitions are merged, generating only a single variable.
NEW: .nsddef files can now be opened by drag&drop from Windows Explorer.
NEW: IDE layout can now be reset through View menu item "Reset layout".
FIX: Property are now stored into .nsddef only if value is different from default.
FIX: Fixed issue on copy/paste controls (duplicate control name).
FIX: User custom scripts won't be generated during debug, avoiding compile error due to missing functions.

v.0.9.8 - 2011-09-12
NEW: Script editor/preview now has NSIS syntax highlighting and code folding,
thanks to FastColoredTextBox
(LGPL3 control, see here: http://www.codeproject.com/KB/edit/FastColoredTextBox_.aspx)
FIX: Styles property wrongly uses the value of ExStyles property.

v.0.9.7 - 2011-09-11
NEW: Added support for Unicode into generated .nsdinc scripts (needs an Unicode version of NSIS).
NEW: New (self explaining) control properties: Visible and Enabled.
NEW: Dialog name (and so the corresponding NSIS variable) can now be set independently
from its .nsddef filename. It could be set through the new "Name" dialog property.
FIX: Generated test script (the one compiled with F5) now checks user
custom scripts to avoid redefining an already defined function.
(thanks to Benjamin Richardson for reporting bug)
FIX: Fixed broken uninstall test script.
FIX: Some properties appear in bold into Property Grid, even if their
value is the default one. This caused the generate script to be longer than required.
FIX: Custom script editor now accepts TAB key.
FIX: Script preview is cleared when closing the last dialog editor.
FIX: Fixed focus management issues that prevents DEL key to work into PropertyGrid.

v.0.9.6 - 2011-06-28
NEW: Added new property SetupType to dialog, allowing the generated script to be used
in both Install and Uninstall scripts.
NEW: Debugger code to debug Uninstaller dialogs.
FIX: Cleaned up the debug scripts.

v.0.9.5 - 2011-06-16
BUG: Fixed key management preventing DEL key to be used inside PropertyGrid (thanks to Jovet for bug report)
NEW: Edit menu items now are enabled according to active content (designer, property, toolbox, ...)
NEW: DialogID and Size now are public properties (deedsmedia request)
(can be reset to default values by right-clicking on PropertyGrid item)

v.0.9.4 - 2011-05-29
BUG: Fixed permission issues on UAC enabled systems.

v.0.9.3 - 2011-04-20
NEW: Added new properties ForeColor and BackColor
(not working for: Button, ComboBox, DropList, GroupBox, HLine, VLine, ProgressBar)
NEW: Added new property Font
NEW: Designer now can show a grid (see Tools | Options menu)
BUG: Editor does not save dialogs when exiting with close button.
BUG: Script preview not updated when a new control is added

v.0.9.2 - 2011-04-20
BUG: Missing property "Name" is now shown
(Dialog does not have it because name is the same as its definition filename)

v.0.9.1 - 2011-04-20
NEW: New dockable content with realtime NSIS generated script preview

v.0.9.0 - 2011-04-18
First public release
</pre>

Driver installation and update

2013-01-16T00:00:58Z

Dsuess: /* The Header */ Added ALL constant definitions for UpdateDriverForPlugAndPlayDevices(..)

{{PageAuthor|kuba}}

== Description ==
I always thought it's not very nice nor professional to have users hunt for a driver when a device is attached to their system. Especially if there's some application software for that device that they install anyway.

Wouldn't it be nice if the user could just install the software, which would install the driver automatically? And then they plug in their device and windows already knows where the driver is! It'd be even better if the driver could be updated without having to disconnect the device, right? Well, the attached script does that too -- on 2000/XP, that is. For Vista and above try the MS [http://msdn.microsoft.com/en-us/library/ff550419%28v=vs.85%29.aspx PnPUtil] utility.

First, let's define some winapi functions. These go into drvsetup.nsh

== The Header ==
<highlight-nsis>
/*
BOOL UpdateDriverForPlugAndPlayDevices(
_In_opt_ HWND hwndParent,
_In_ LPCTSTR HardwareId,
_In_ LPCTSTR FullInfPath,
_In_ DWORD InstallFlags,
_Out_opt_ PBOOL bRebootRequired
);
*/
!define sysUpdateDriverForPlugAndPlayDevices "newdev::UpdateDriverForPlugAndPlayDevices(i, t, t, i, *i) i"
!define NO_ERROR 0
!define ERROR_FILE_NOT_FOUND 2
!define ERROR_IN_WOW64 -536870347 ; 0xE0000235
!define ERROR_INVALID_FLAGS 1004 ; 0x3EC
!define ERROR_NO_SUCH_DEVINST -536870389 ; 0xE000020B
; the masked value of ERROR_NO_SUCH_DEVINST is 523

!define INSTALLFLAG_FORCE 0x1
!define INSTALLFLAG_READONLY 0x2
!define INSTALLFLAG_NONINTERACTIVE 0x4
; Use FORCE flag ex: pushing an older release over top of new one.

;BOOL SetupCopyOEMInf(PSTR, PSTR, DWORD, DWORD, PSTR, DWORD, PDWORD, PSTR);
!define sysSetupCopyOEMInf "setupapi::SetupCopyOEMInf(t, t, i, i, i, i, *i, t) i"
!define SPOST_NONE 0
!define SPOST_PATH 1
!define SPOST_URL 2
!define SP_COPY_DELETESOURCE 0x1
!define SP_COPY_REPLACEONLY 0x2
!define SP_COPY_NOOVERWRITE 0x8
!define SP_COPY_OEMINF_CATALOG_ONLY 0x40000</highlight-nsis>

And then the actual function, which goes into driver.nsh. Note that it assumes you have [[Get_Windows_version|GetWindowsVersion]] function pasted into "winver.nsh".

== The Function ==
<highlight-nsis>
!include "winver.nsh"
!include "drvsetup.nsh"

;
; Written by Kuba Ober
; Copyright (c) 2004 Kuba Ober
;
; Permission is hereby granted, free of charge, to any person obtaining a
; copy of this software and associated documentation files (the "Software"),
; to deal in the Software without restriction, including without limitation
; the rights to use, copy, modify, merge, publish, distribute, sublicense,
; and/or sell copies of the Software, and to permit persons to whom the
; Software is furnished to do so, subject to the following conditions:
;
; The above copyright notice and this permission notice shall be included in
; all copies or substantial portions of the Software.
;
; THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
; IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
; FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
; AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
; LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
; FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
; DEALINGS IN THE SOFTWARE.

;
; U S A G E
;
; Push "c:\program files\yoursoftware\driver"
; -- the directory of the .inf file
; Push "c:\program files\yoursoftware\driver\driver.inf"
; -- the filepath of the .inf file (directory + filename)
; Push "USB\VID_1234&PID_5678"
; -- the HID (Hardware ID) of your device
; Call InstallUpgradeDriver
;
; Your driver (minimally the .inf and .sys files) should already by installed
; by your NSIS script.
;
; Typically, you would put the driver either in $INSTDIR or $INSTDIR\Driver
; It's up to you, of course.
;
; The driver (i.e. .inf, .sys and related files) must be present for the
; lifetime of your application, you shouldn't remove them after calling
; this function!
;
; You DON'T want to put the driver in any of system directories. Windows
; will do it when the device is first plugged in.

Function InstallUpgradeDriver

Pop $R0 ; HID
Pop $R1 ; INFPATH
Pop $R2 ; INFDIR

; Get the Windows version
Call GetWindowsVersion
Pop $R3 ; Windows Version
;DetailPrint 'Windows Version: $R3'
StrCmp $R3 '2000' lbl_upgrade
StrCmp $R3 'XP' lbl_upgrade
StrCmp $R3 '2003' lbl_upgrade
DetailPrint "Windows $R3 doesn't support automatic driver updates."

; Upgrade the driver if the device is already plugged in
Goto lbl_noupgrade
lbl_upgrade:
System::Get '${sysUpdateDriverForPlugAndPlayDevices}'
Pop $0
StrCmp $0 'error' lbl_noapi
DetailPrint "Updating the driver..."
; 0, HID, INFPATH, 0, 0
Push $INSTDIR ; Otherwise this function will swallow it, dunno why
System::Call '${sysUpdateDriverForPlugAndPlayDevices}?e (0, R0, R1, 0, 0) .r0'
Pop $1 ; last error
Pop $INSTDIR
IntCmp $0 1 lbl_done
IntCmp $1 ${ERROR_NO_SUCH_DEVINST} lbl_notplugged

DetailPrint "Driver update has failed. ($R3:$0,$1)"
Goto lbl_noupgrade
lbl_notplugged:
DetailPrint "The device is not plugged in, cannot update the driver."
Goto lbl_noupgrade
lbl_noapi:
DetailPrint "Your Windows $R3 doesn't support driver updates."

lbl_noupgrade:
; Pre-install the driver
System::Get '${sysSetupCopyOEMInf}'
Pop $0
StrCmp $0 'error' lbl_inoapi
DetailPrint "Installing the driver..."
; INFPATH, INFDIR, SPOST_PATH, "", 0, 0, 0, 0
System::Call '${sysSetupCopyOEMInf}?e (R1, R2, ${SPOST_PATH}, 0, 0, 0, 0, 0) .r0'
Pop $1 ; last error
IntCmp $0 1 lbl_nodriver
DetailPrint 'Driver pre-installation has failed with error #$1 ($R3)'
Goto lbl_done
lbl_inoapi:
DetailPrint "Your Windows $R3 doesn't support driver pre-installation."
lbl_nodriver:
lbl_done:

FunctionEnd</highlight-nsis>

[[Category:System Related Functions]]

Useful InstallOptions and MUI macros

2012-05-17T18:12:50Z

Dsuess: /* sample.ini */ Changed NumFields from 16 to 15. It would not load in HM NIS Edit otherwise

{{PageAuthor|bholliger}}

== Description ==

I created some macros that are useful for some InstallOptions tasks. Feel free to use and/or add your own macros as well. I hope they are useful.

== General tips and hints for InstallOptions ==

Due to the fact that the field numbers define the tab-order this might change after adding another element to the dialog. Therefore I recommend using constants that hold the field names in a single location. This improves the general readability of the code as well.

<highlight-nsis>
;----------------------
;defines for Dialog 1 - sample.ini

!define DIALOG1 "sample.ini"

!define CHK_BLUE "Field 2"
!define CHK_RED "Field 3"
!define CHK_GREEN "Field 4"
!define CHK_BROWN "Field 5"
!define CHK_PROXYSETTINGS "Field 6"
!define GRP_PROXYOPTIONS "Field 7"
!define LBL_IPADDRESS "Field 8"
!define TXT_IPADDRESS "Field 9"
!define LBL_PORT1 "Field 10"
!define TXT_PORT1 "Field 11"
!define CHK_ENCRYPTION "Field 12"
!define DRQ_NSISPATH "Field 14"
!define CMD_AUTODETECTNSISPATH "Field 15"
</highlight-nsis>

== Macro: GROUPCONTROLS ==

Activate a group of controls according to another control like a checkbox.

<highlight-nsis>
; Activate a group of controls, depending on the state of one control
;
; Usage:
;
; eg. !insertmacro GROUPCONTROLS "${DIALOG1}" "${CHK_PROXYSETTINGS}"
; "${LBL_IPADDRESS}|${TXT_IPADDRESS}|${LBL_PORT1}|${TXT_PORT1}|${CHK_ENCRYPTION}"
; FILE: INI-file in $pluginsdir
; SOURCECONTROL: RadioButton, Checkbox
; CONTROLGROUP: pipe delimited list of controls; ${BUTTON1}|${CHECKBOX}|${TEXTFIELD}
;
; Requires:
;
; !include "WordFunc.nsh"
; !insertmacro WordReplace
; !insertmacro WordFind
;
!macro GROUPCONTROLS FILE SOURCECONTROL CONTROLGROUP
Push $R0 ;holds element
Push $R1 ;counter
Push $R2 ;state of the control
Push $R3 ;flags of the control / hwnd of the control

!insertmacro MUI_INSTALLOPTIONS_READ $R2 "${FILE}" "${SOURCECONTROL}" "State"

StrCpy $R1 1
${Do}
ClearErrors
${WordFind} "${CONTROLGROUP}" "|" "E+$R1" $R0

${If} ${Errors}
${OrIf} $R0 == ""
${ExitDo}
${EndIf}

; Put state change in flags of element as well
!insertmacro MUI_INSTALLOPTIONS_READ $R3 "${FILE}" "$R0" "Flags"
${If} "$R2" == "1"
${WordReplace} $R3 "DISABLED" "" "+" $R3
${WordReplace} $R3 "||" "|" "+" $R3
!insertmacro MUI_INSTALLOPTIONS_WRITE "${FILE}" "$R0" "Flags" $R3
${Else}
!insertmacro MUI_INSTALLOPTIONS_WRITE "${FILE}" "$R0" "Flags" "$R3|DISABLED"
${EndIf}

!insertmacro MUI_INSTALLOPTIONS_READ $R3 "${FILE}" "$R0" "HWND"
EnableWindow $R3 $R2

IntOp $R1 $R1 + 1
${Loop}

Pop $R3
Pop $R2
Pop $R1
Pop $R0

!macroend
</highlight-nsis>

== Macro: CHANGETEXTFIELD ==

Change the content of a textfield and write it to ini file. Ideal for autodetect purposes.

<highlight-nsis>
;change text field and put value in ini file
;
; Usage:
;
; !insertmacro CHANGETEXTFIELD "${DIALOG1}" "${DRQ_NSISPATH}" $tmp
;
; FILE: INI-file in $pluginsdir
; ELEMENT: name of the control
; VALUE: value that should appear in control
;
!macro CHANGETEXTFIELD FILE ELEMENT VALUE
Push $R0 ; holds value
!insertmacro MUI_INSTALLOPTIONS_WRITE ${VALUE} "${FILE}" "${ELEMENT}" "State"
!insertmacro MUI_INSTALLOPTIONS_READ $R0 "${FILE}" "${ELEMENT}" "HWND"
SendMessage $R0 ${WM_SETTEXT} 0 "STR:${VALUE}"
Pop $R0
!macroend
</highlight-nsis>

== Macro: CHECKBOXCHECKER ==

Counts the number of activated controls and displays an error message if there are not enough controls selected. Select 3 or 4 out of 6.

<highlight-nsis>
; checks a group of checkboxes and counts how many of them
; are activated.
;
; Usage:
;
; Create a langstring containing an error message
; eg. LangString TEXT_LIMITATIONSEXEEDED ${LANG_ENGLISH} "Choose either two or three colours!"
;
; eg. !insertmacro CHECKBOXCHECKER "${DIALOG1}" "${CHK_BLUE}|${CHK_RED}|${CHK_GREEN}|${CHK_BROWN}" 2 3
;
; FILE: INI-file in $pluginsdir
; CONTROLGROUP: pipe delimited list of controls; ${BUTTON1}|${CHECKBOX}|${TEXTFIELD}
; MIN/MAX: at least ${MIN} and no more than ${MAX} controls must be in activated state
;
; Requires:
;
; !include "WordFunc.nsh"
; !insertmacro WordFind
;
!macro CHECKBOXCHECKER FILE CONTROLGROUP MIN MAX

Push $R0 ;holds element
Push $R1 ;counter
Push $R2 ;count activated elements
Push $R3 ;state of the control

StrCpy $R1 1
StrCpy $R2 0
${Do}
ClearErrors
${WordFind} "${CONTROLGROUP}" "|" "E+$R1" $R0

${If} ${Errors}
${OrIf} $R0 == ""
${ExitDo}
${EndIf}

; Put state change in flags of element as well
!insertmacro MUI_INSTALLOPTIONS_READ $R3 "${FILE}" "$R0" "State"
${If} "$R3" == "1"
IntOp $R2 $R2 + 1
${EndIf}

IntOp $R1 $R1 + 1
${Loop}

${If} $R2 < ${MIN}
${OrIf} $R2 > ${MAX}
MessageBox MB_OK|MB_ICONSTOP "$(TEXT_LIMITATIONSEXCEEDED)"
Abort
${EndIf}

Pop $R3
Pop $R2
Pop $R1
Pop $R0

!macroend
</highlight-nsis>

== Sample ==

Have a look at the sample.

<highlight-nsis>
;---------------------
;Include Modern UI

!include "MUI.nsh"
!include "LogicLib.nsh"
;----------------------
;defines for Dialog 1 - sample.ini

!define DIALOG1 "sample.ini"

!define CHK_BLUE "Field 2"
!define CHK_RED "Field 3"
!define CHK_GREEN "Field 4"
!define CHK_BROWN "Field 5"
!define CHK_PROXYSETTINGS "Field 6"
!define GRP_PROXYOPTIONS "Field 7"
!define LBL_IPADDRESS "Field 8"
!define TXT_IPADDRESS "Field 9"
!define LBL_PORT1 "Field 10"
!define TXT_PORT1 "Field 11"
!define CHK_ENCRYPTION "Field 12"
!define DRQ_NSISPATH "Field 14"
!define CMD_AUTODETECTNSISPATH "Field 15"
;--------------------------------
;General

;Name and file
Name "MUI installation validation example"
OutFile "test.exe"

;Default installation folder
InstallDir "$PROGRAMFILES\MUI validate"

;Get installation folder from registry if available
InstallDirRegKey HKCU "Software\MUI validate" ""

;--------------------------------
;Pages

Page custom InitPage ValidatePage
!insertmacro MUI_PAGE_DIRECTORY
!insertmacro MUI_PAGE_INSTFILES

;--------------------------------
;Interface Settings

!define MUI_ABORTWARNING

;--------------------------------
;Languages

!insertmacro MUI_LANGUAGE "English"

;--------------------------------
;Reserve Files

;If you are using solid compression, files that are required before
;the actual installation should be stored first in the data block,
;because this will make your installer start faster.

ReserveFile "sample.ini"
!insertmacro MUI_RESERVEFILE_INSTALLOPTIONS

;--------------------------------
;Variables

Var "tmp"

!include "WordFunc.nsh"
!insertmacro WordReplace
!insertmacro WordFind

; Activate a group of controls, depending on the state of one control
;
; Usage:
;
; eg. !insertmacro GROUPCONTROLS "${DIALOG1}" "${CHK_PROXYSETTINGS}" "${LBL_IPADDRESS}|${TXT_IPADDRESS}|${LBL_PORT1}|${TXT_PORT1}|${CHK_ENCRYPTION}"
; FILE: INI-file in $pluginsdir
; SOURCECONTROL: RadioButton, Checkbox
; CONTROLGROUP: pipe delimited list of controls; ${BUTTON1}|${CHECKBOX}|${TEXTFIELD}
;
; Requires:
;
; !include "WordFunc.nsh"
; !insertmacro WordReplace
; !insertmacro WordFind
;
!macro GROUPCONTROLS FILE SOURCECONTROL CONTROLGROUP
Push $R0 ;holds element
Push $R1 ;counter
Push $R2 ;state of the control
Push $R3 ;flags of the control / hwnd of the control

!insertmacro MUI_INSTALLOPTIONS_READ $R2 "${FILE}" "${SOURCECONTROL}" "State"

StrCpy $R1 1
${Do}
ClearErrors
${WordFind} "${CONTROLGROUP}" "|" "E+$R1" $R0

${If} ${Errors}
${OrIf} $R0 == ""
${ExitDo}
${EndIf}

; Put state change in flags of element as well
!insertmacro MUI_INSTALLOPTIONS_READ $R3 "${FILE}" "$R0" "Flags"
${If} "$R2" == "1"
${WordReplace} $R3 "DISABLED" "" "+" $R3
${WordReplace} $R3 "||" "|" "+" $R3
!insertmacro MUI_INSTALLOPTIONS_WRITE "${FILE}" "$R0" "Flags" $R3
${Else}
!insertmacro MUI_INSTALLOPTIONS_WRITE "${FILE}" "$R0" "Flags" "$R3|DISABLED"
${EndIf}

!insertmacro MUI_INSTALLOPTIONS_READ $R3 "${FILE}" "$R0" "HWND"
EnableWindow $R3 $R2

IntOp $R1 $R1 + 1
${Loop}

Pop $R3
Pop $R2
Pop $R1
Pop $R0

!macroend

;change text field and put value in ini file
;
; Usage:
;
; !insertmacro CHANGETEXTFIELD "${DIALOG1}" "${DRQ_NSISPATH}" $tmp
;
; FILE: INI-file in $pluginsdir
; ELEMENT: name of the control
; VALUE: value that should appear in control
;
!macro CHANGETEXTFIELD FILE ELEMENT VALUE
Push $R0 ; holds value
!insertmacro MUI_INSTALLOPTIONS_WRITE ${VALUE} "${FILE}" "${ELEMENT}" "State"
!insertmacro MUI_INSTALLOPTIONS_READ $R0 "${FILE}" "${ELEMENT}" "HWND"
SendMessage $R0 ${WM_SETTEXT} 0 "STR:${VALUE}"
Pop $R0
!macroend

; checks a group of checkboxes and counts how many of them
; are activated.
;
; Usage:
;
; Create a langstring containing an error message
; eg. LangString TEXT_LIMITATIONSEXEEDED ${LANG_ENGLISH} "Choose either two or three colours!"
;
; eg. !insertmacro CHECKBOXCHECKER "${DIALOG1}" "${CHK_BLUE}|${CHK_RED}|${CHK_GREEN}|${CHK_BROWN}" 2 3
;
; FILE: INI-file in $pluginsdir
; CONTROLGROUP: pipe delimited list of controls; ${BUTTON1}|${CHECKBOX}|${TEXTFIELD}
; MIN/MAX: at least ${MIN} and no more than ${MAX} controls must be in activated state
;
; Requires:
;
; !include "WordFunc.nsh"
; !insertmacro WordFind
;
!macro CHECKBOXCHECKER FILE CONTROLGROUP MIN MAX

Push $R0 ;holds element
Push $R1 ;counter
Push $R2 ;count activated elements
Push $R3 ;state of the control

StrCpy $R1 1
StrCpy $R2 0
${Do}
ClearErrors
${WordFind} "${CONTROLGROUP}" "|" "E+$R1" $R0

${If} ${Errors}
${OrIf} $R0 == ""
${ExitDo}
${EndIf}

; Put state change in flags of element as well
!insertmacro MUI_INSTALLOPTIONS_READ $R3 "${FILE}" "$R0" "State"
${If} "$R3" == "1"
IntOp $R2 $R2 + 1
${EndIf}

IntOp $R1 $R1 + 1
${Loop}

${If} $R2 < ${MIN}
${OrIf} $R2 > ${MAX}
MessageBox MB_OK|MB_ICONSTOP "$(TEXT_LIMITATIONSEXCEEDED)"
Abort
${EndIf}

Pop $R3
Pop $R2
Pop $R1
Pop $R0

!macroend

;--------------------------------
;Installer Sections

Section "Dummy Section" SecDummy

SetOutPath "$INSTDIR"

;ADD YOUR OWN FILES HERE...

SectionEnd

;--------------------------------
;Installer Functions

Function .onInit

; !insertmacro MUI_LANGDLL_DISPLAY

FunctionEnd

LangString TEXT_IO_TITLE ${LANG_ENGLISH} "Test page"
LangString TEXT_IO_SUBTITLE ${LANG_ENGLISH} "Test some things"
LangString TEXT_LIMITATIONSEXCEEDED ${LANG_ENGLISH} "Choose either two or three colours!"

Function InitPage

;Extract InstallOptions INI files
!insertmacro MUI_INSTALLOPTIONS_EXTRACT "${DIALOG1}"

!insertmacro MUI_HEADER_TEXT "$(TEXT_IO_TITLE)" "$(TEXT_IO_SUBTITLE)"
!insertmacro MUI_INSTALLOPTIONS_INITDIALOG "${DIALOG1}"
!insertmacro GROUPCONTROLS "${DIALOG1}" "${CHK_PROXYSETTINGS}" "${LBL_IPADDRESS}|${TXT_IPADDRESS}|${LBL_PORT1}|${TXT_PORT1}|${CHK_ENCRYPTION}"
!insertmacro MUI_INSTALLOPTIONS_SHOW

FunctionEnd

Function ValidatePage
; handle notify event of element
!insertmacro MUI_INSTALLOPTIONS_READ $tmp "${DIALOG1}" "Settings" "State"
${Switch} "Field $tmp"
${Case} "${CHK_PROXYSETTINGS}"
!insertmacro GROUPCONTROLS "${DIALOG1}" "${CHK_PROXYSETTINGS}" "${LBL_IPADDRESS}|${TXT_IPADDRESS}|${LBL_PORT1}|${TXT_PORT1}|${CHK_ENCRYPTION}"
Abort
${Case} "${CMD_AUTODETECTNSISPATH}"
;read registry value and set text field
ReadRegStr $tmp HKLM "Software\NSIS" ""
!insertmacro CHANGETEXTFIELD "${DIALOG1}" "${DRQ_NSISPATH}" $tmp
Abort
${EndSwitch}

; check if 2 or 3 check boxes are activated
!insertmacro CHECKBOXCHECKER "${DIALOG1}" "${CHK_BLUE}|${CHK_RED}|${CHK_GREEN}|${CHK_BROWN}" 2 3

; check if checkbox is activated
!insertmacro MUI_INSTALLOPTIONS_READ $tmp "${DIALOG1}" "${CHK_PROXYSETTINGS}" "State"
${If} $tmp == 1
Var /GLOBAL ip1
Var /GLOBAL port1

!insertmacro MUI_INSTALLOPTIONS_READ $ip1 "${DIALOG1}" "${TXT_IPADDRESS}" "State"
Push "$ip1"
Call ValidateIP
${If} ${Errors}
MessageBox MB_ICONEXCLAMATION "IP not correct! $ip1"
Abort
${EndIf}

!insertmacro MUI_INSTALLOPTIONS_READ $port1 "${DIALOG1}" "${TXT_PORT1}" "State"
${If} $port1 < 1024
${OrIf} $port1 > 32768
MessageBox MB_ICONEXCLAMATION "Port not valid!"
Abort
${EndIf}
${EndIf}

; check for file in NSIS' path
!insertmacro MUI_INSTALLOPTIONS_READ $tmp "${DIALOG1}" "${DRQ_NSISPATH}" "State"
${Unless} ${FileExists} "$tmp\makensis.exe"
MessageBox MB_OK|MB_ICONEXCLAMATION "makensis.exe in NSIS path not found!"
Abort
${EndIf}

; TODO: save values to ini file/registry...

FunctionEnd

; http://nsis.sourceforge.net/Validate_IP_function
!include WordFunc.nsh

!insertmacro WordFind
!insertmacro StrFilter
Function ValidateIP

Exch $0
Push $1
Push $2

${StrFilter} $0 1 "." "" $1
${If} $0 != $1
# invalid charcaters used
# example: a127.0.0.1
Goto error
${EndIf}

${WordFind} $0 . "#" $1
${If} $1 != 4
# wrong number of numbers
# example: 127.0.0.
Goto error
${EndIf}

${WordFind} $0 . "*" $1
${If} $1 != 3
# wrong number of dots
# example: 127.0.0.1.
Goto error
${EndIf}

${For} $2 1 4
${WordFind} $0 . +$2 $1

${If} $1 > 255
${OrIf} $1 < 0
# invalid number
# example: 500.0.0.1
Goto error
${EndIf}
${Next}

Pop $2
Pop $1
Pop $0

ClearErrors

Return

error:

Pop $2
Pop $1
Pop $0

SetErrors

FunctionEnd
</highlight-nsis>

== sample.ini ==

<highlight-nsis>
; Ini file generated by the HM NIS Edit IO designer.
[Settings]
NumFields=15

[Field 1]
Type=Groupbox
Text=Colour (choose 2 or 3)
Left=0
Right=112
Top=0
Bottom=56

[Field 2]
Type=CheckBox
Text=&Blue
Left=5
Right=80
Top=10
Bottom=20
State=0

[Field 3]
Type=CheckBox
Text=&Red
Left=5
Right=80
Top=20
Bottom=30

[Field 4]
Type=CheckBox
Text=&Green
Left=5
Right=80
Top=30
Bottom=40

[Field 5]
Type=CheckBox
Text=&Brown
Left=5
Right=79
Top=40
Bottom=49

[Field 6]
Type=Checkbox
Text=&Set proxy options (NOTIFY)
Flags=NOTIFY
Left=117
Right=225
Top=0
Bottom=10

[Field 7]
Type=Groupbox
Left=117
Right=-1
Top=10
Bottom=56
Text=Proxy options

[Field 8]
Type=Label
Text=&IP-Address:
Left=122
Right=165
Top=22
Bottom=30

[Field 9]
Type=Text
Left=122
Right=240
Top=30
Bottom=42

[Field 10]
Type=Label
Text=&Port:
Left=244
Right=264
Top=22
Bottom=30

[Field 11]
Type=Text
Left=244
Right=-10
Top=30
Bottom=42

[Field 12]
Type=Checkbox
Text=&Use encryption
Left=122
Right=187
Top=44
Bottom=54

[Field 13]
Type=Groupbox
Text=Set NSIS path or click autodetect
Left=117
Right=-1
Top=61
Bottom=116

[Field 14]
Type=DirRequest
Left=122
Right=-10
Top=77
Bottom=89

[Field 15]
Type=Button
Text=&Autodetect
Flags=NOTIFY
Left=245
Right=-10
Top=92
Bottom=106
</highlight-nsis>

[[Category:Code Examples]]

Project Procyon

2012-05-08T23:32:35Z

Dsuess: line formatting

== Description ==
The auto-updater used in [http://procyon.surrealearth.info/ Project Procyon].

This work is licensed under a [http://creativecommons.org/licenses/by-nc/3.0/ Creative Commons Attribution-NonCommercial 3.0 Unported License].

== The Script ==
<highlight-nsis>
; NSIS script for Project Procyon Alpha Launcher
; Written in 2010 by Troy Martin for Project Procyon.
; Project Procyon site: http://procyon.surrealearth.info/
; Licensed under a Creative Commons Attribution-NonCommercial 3.0 License.
; See http://creativecommons.org/licenses/by-nc/3.0/ for license details.

; String defines
!define PRODUCT_NAME "Project Procyon"
!define PRODUCT_VERSION "Alpha"
!define PRODUCT_PUBLISHER "Surreal Earth Studios"
!define PRODUCT_WEB_SITE "http://procyon.surrealearth.info/"

RequestExecutionLevel user ; It works better without wanting admin privs.
Icon "procyon.ico"
BrandingText " " ; Remove the NSIS branding text

!include "UAC.nsh" ; I don't know why this is included.

Name "${PRODUCT_NAME} ${PRODUCT_VERSION}"
OutFile "procyon.exe"
InstallDir "$PROGRAMFILES\Project Procyon"
ShowInstDetails show

Section "MainSection" SEC01

IfFileExists "$AppData\Procyon\*.*" +2 ; Procyon goes into AppData for ease
CreateDirectory "$AppData\Procyon" ; of launching and updating.

; Future revisions may include launcher auto-update. Code is written, but no
; launcher update files are on the Procyon server yet.

; You can always add "Call DetectLauncherUpdate" here, but the code in that
; function and related functions are not tested.

Call DetectProcyonUpdate ; All the code for the launcher is function-based.

SectionEnd

Section -Post
SectionEnd

Function RunProcyon
IfFileExists "$AppData\Procyon\procyon.exe" +4
Delete "$AppData\Procyon\version.txt"
Call DetectProcyonUpdate
Quit
Exec '"$AppData\Procyon\procyon.exe"'
Quit
FunctionEnd

Function GetProcyon
FileOpen $0 "$AppData\Procyon\version.txt" r
FileRead $0 $3
FileClose $0
StrCpy $3 $3 -2
StrCpy $2 "$AppData\Procyon\procyon.exe"
Rename $2 "$AppData\Procyon\procyonold.exe"
nsisdl::download /TIMEOUT=30000 "${PRODUCT_WEB_SITE}updater/procyon-$3.zip" "$AppData\Procyon\procyon.zip"
Pop $R0 ;Get the return value
StrCmp $R0 "success" +4
MessageBox MB_OK "Download failed: $R0 - $3.zip"
Rename "$AppData\Procyon\procyonold.exe" $2
Quit
nsisunz::UnzipToLog "$AppData\Procyon\procyon.zip" "$AppData\Procyon"
Delete "$AppData\Procyon\procyon.zip"
Call RunProcyon
FunctionEnd

Function DetectProcyonUpdate
StrCpy $2 "$TEMP\procyonupdate.txt"

nsisdl::download /TIMEOUT=30000 "${PRODUCT_WEB_SITE}updater/procyonupdate.txt" $2
Pop $R0 ;Get the return value
StrCmp $R0 "success" +3
MessageBox MB_OK "Download failed: $R0"
Call RunProcyon
FileOpen $0 "$TEMP\procyonupdate.txt" r
FileRead $0 $1
FileClose $0
IfFileExists "$AppData\Procyon\*.*" 0 +5
FileOpen $0 "$AppData\Procyon\version.txt" r
FileRead $0 $3
FileClose $0
StrCmp $1 $3 +5
FileOpen $0 "$AppData\Procyon\version.txt" w
FileWrite $0 $1
FileClose $0
Call GetProcyon
Call RunProcyon
FunctionEnd

Function RunLauncher ; Never actually called
Exec $EXEPATH
Quit
FunctionEnd

Function GetLauncher ; Never actually called
nsisdl::download /TIMEOUT=30000 "${PRODUCT_WEB_SITE}procyon.exe" $EXEPATH
Pop $R0 ;Get the return value
StrCmp $R0 "success" +4
MessageBox MB_OK "Download failed: $R0 - $3.exe"
Quit
Call RunLauncher
FunctionEnd

Function DetectLauncherUpdate ; Never actually called
StrCpy $2 "$TEMP\launcherupdate.txt"

nsisdl::download /TIMEOUT=30000 "${PRODUCT_WEB_SITE}updater/launcherupdate.txt" $2
Pop $R0 ;Get the return value
StrCmp $R0 "success" +3
MessageBox MB_OK "Download failed: $R0"
Return
FileOpen $0 "$TEMP\launcherupdate.txt" r
FileRead $0 $1
FileClose $0
IfFileExists "$AppData\Procyon\*.*" 0 +5
FileOpen $0 "$AppData\Procyon\launcher.txt" r
FileRead $0 $3
FileClose $0
StrCmp $1 $3 +5
FileOpen $0 "$AppData\Procyon\launcher.txt" w
FileWrite $0 $1
FileClose $0
Call GetLauncher
Call RunLauncher
FunctionEnd
</highlight-nsis>
{{PageAuthor|Kazinsal}}

[[Category:Real_World_Installers]]

"Orange Vista" Modern UI Theme

2007-05-15T21:52:33Z

Dsuess: added link for download

<center>http://www.monki.es/images/stories/orange/image1.jpg</center> <br/><br/>

== Descripton ==

The "Orange Vista Modern UI Theme" is a professional collection of icons and bitmaps with a Windows Vista style for NullSoft Scriptable Install System (NSIS) and his Modern UI.

It has 9 styles, each one with his own installer/uninstaller icon, headers and welcome bitmaps.

The icons have the new 256x256 icon format and adapts perfectly with the look and feel of Windows Vista.

The theme is an evolution of my old [["Orange" Modern UI Theme]].

== Donwload ==

You can get more info, see more screenshots and download it from here: [http://www.monki.es/blog/diseno/nsis-orange-vista-theme.html http://www.monki.es]

Or download the 7z file directly here:
[http://www.monki.es/descargas/nsis/orange_vista/MUIOrangeVistaTheme.7z MUIOrangeVistaTheme.7z]

== Screenshots ==

<center>http://www.monki.es/images/stories/orange/image3.jpg
http://www.monki.es/images/stories/orange/image4.jpg<br/><br/>
http://www.monki.es/images/stories/orange/image2.jpg</center>

[[Category:Graphics and UIs]]