View source for Enhanced FindWindow for variable window class names

{{PageAuthor|Comm@nder21}}

== Introduction ==
Sometimes, you want to send messages to a window, that you don't know the full window class name (wcn) of, or it contains variables and you know the constant part. So you can't use FindWindow, that doesn't support wildcars.
This function doesn't too. But you can get the handle of any window, whith only one known part of the wcn.

== Usage ==
Simply call this function. At the moment, all variables are hardcoded, so you don't have to push anything. Maybe, i'll add this possibility later.
<highlight-nsis>
Push  0   # the starting offset of the push below
Push  "Application"   # the known part of the class name
Call  EnhancedFindWindow
Pop  $0   # will contain the window's handle
Pop  $1   # will containg the full wcn
          # both will containg "failed", if no matching wcn was found
</highlight-nsis>

== The Function ==
<highlight-nsis>
Function  EnhancedFindWindow
  ; input, save variables
  Exch  $0   # part of the class name to search for
  Exch
  Exch  $1   # starting offset
  Push  $2   # length of $0
  Push  $3   # window handle
  Push  $4   # class name
  Push  $5   # temp

  ; set up the variables
  StrCpy  $4  0
  StrLen  $2  $0

 ; loop to search for open windows
 search_loop:
  FindWindow  $3  ""  ""  0  $3
   IntCmp  $3  0  search_failed
    IsWindow  $3  0  search_loop
     System::Call 'user32.dll::GetClassName(i r3, t .r4, i ${NSIS_MAX_STRLEN}) i .n'
     StrCmp  $4  0  search_loop
     StrCpy  $5  $4  $2  $1
     StrCmp  $0  $5  search_end  search_loop

 ; no matching class-name found, return "failed"
 search_failed:
  StrCpy  $3  "failed"
  StrCpy  $4  "failed"

 ; search ended, output and restore variables
 search_end:
  StrCpy  $1  $3
  StrCpy  $0  $4
  Pop  $5
  Pop  $4
  Pop  $3
  Pop  $2
  Exch  $1
  Exch
  Exch  $0
FunctionEnd
</highlight-nsis>

== Feedback ==
Any suggestions, feature requests or even bug reports?
Feel free to send me [http://forums.winamp.com/member.php?s=&action=mailform&userid=117645 an email] or [http://forums.winamp.com/private.php?s=&action=newmessage&userid=117645 a private message].

Please post any other question, e.g. about usage and customization at the [http://forums.winamp.com/forumdisplay.php?forumid=65 NSIS forums].
Remember: You're not alone ...

== Further Reading ==
See [http://forums.winamp.com/showthread.php?s=&threadid=172415 this topic] for more information about the function itself and alternatives.
See [http://msdn.microsoft.com/library/default.asp?url=/library/en-us/winui/WinUI/WindowsUserInterface/Windowing/WindowClasses/WindowClassReference/WindowClassFunctions/GetClassName.asp the msdn] for more information about the user32 api call "GetClassName".

[[Category:User Interface Functions]]