View source for Removing MSI packages with MSI related functions

{{PageAuthor|MathiasSimmack}}

== Description ==
This is an extension to [[Uninstalling a previous MSI (Windows installer package)]]. It's another version to remove an installed MSI product. I wrote a simple function and a few symbols:

== How To Use ==
What you need is the ProductID (ProductCode) of your previous MSI installation. Send it onto the stack and call the function
<highlight-nsis>Push "{48E5A72D-whatever-xxxx}"
call CallMsiDeinstaller</highlight-nsis>

== The Function ==
<highlight-nsis>!define OLDVERSIONWARNING \
  "An older version of $(^Name) was found on your system. It is recommended that you uninstall the old version before installing the new version.$\r$\n$\r$\nDo you want to uninstall the old version of $(^Name)?"
!define OLDVERSIONREMOVEERROR \
  "A problem was encountered while removing the old version of $(^Name). Please uninstall it manually using Programs and Features in Control Panel."


!define INSTALLSTATE_DEFAULT "5"
!define INSTALLLEVEL_MAXIMUM "0xFFFF"
!define INSTALLSTATE_ABSENT "2"
!define ERROR_SUCCESS "0"


Function CallMsiDeinstaller
  Pop $R0

  System::Call "msi::MsiQueryProductStateA(t '$R0') i.r0"
  StrCmp $0 "${INSTALLSTATE_DEFAULT}" 0 Done

  MessageBox MB_YESNO|MB_ICONQUESTION "${OLDVERSIONWARNING}" \
  IDNO BreakMe

  System::Call "msi::MsiConfigureProductA(t '$R0', \
    i ${INSTALLLEVEL_MAXIMUM}, i ${INSTALLSTATE_ABSENT}) i.r0"
  StrCmp $0 ${ERROR_SUCCESS} Done

    MessageBox MB_OK|MB_ICONEXCLAMATION \
    "${OLDVERSIONREMOVEERROR}"

  BreakMe:
    Abort

  Done:
FunctionEnd</highlight-nsis>

[[Category:Other Products Handling Functions]]