Advanced Font Installation: Difference between revisions

From NSIS Wiki
Jump to navigationJump to search
m (SF: Lobo Lunar -> Joel.)
m (Put a link to "FontName plugin". Normal font for "FontName plugin" link.)
Line 1: Line 1:
== Description ==
== Description ==
This page uses the functionality of the '''[[FontName]] plugin.'''  This will allow you to register TTF fonts without the need to supply the font's registry name. The second macro is designed to register FON fonts and still requires the input of the font's name. If you do not wish to use the FontName plugin you should use the FON font macro to install TTF fonts.
This page uses the functionality of the [[FontName plugin]]. This will allow you to register TTF fonts without the need to supply the font's registry name. The second macro is designed to register FON fonts and still requires the input of the font's name. If you do not wish to use the FontName plugin you should use the FON font macro to install TTF fonts.


These macros have been designed to work with NSIS 2.0b4 (CVS), although it could possibly be modified to work with earlier versions of NSIS.
These macros have been designed to work with NSIS 2.0b4 (CVS), although it could possibly be modified to work with earlier versions of NSIS.

Revision as of 16:01, 27 April 2005

Description

This page uses the functionality of the FontName plugin. This will allow you to register TTF fonts without the need to supply the font's registry name. The second macro is designed to register FON fonts and still requires the input of the font's name. If you do not wish to use the FontName plugin you should use the FON font macro to install TTF fonts.

These macros have been designed to work with NSIS 2.0b4 (CVS), although it could possibly be modified to work with earlier versions of NSIS.

These macros allow the user to uninstall fonts in the uninstaller as does the standard version the main difference being that if you define FontBackup to a 'registry store' of the fonts the installer created it will only remove fonts that were not present before the program was installed.

Please note that uninstalling fonts is generally not a good idea since other programs might depend on them. Exceptions would be custom created fonts which would only be used by your program or when installing a *huge* amount of fonts.

Save this script as a NSIS Include file in the Include directory of NSIS so that then you can easily get font registration functionality in any script by simply including this file. (Suggested file name: FontRegAdv.nsh)

The Script

var FONT_DIR
!ifndef CSIDL_FONTS
  !define CSIDL_FONTS '0x14' ;Fonts directory path constant
!endif
!ifndef CSIDL_FLAG_CREATE
  !define CSIDL_FLAG_CREATE 0x8000
!endif
 
!macro InstallTTF FontFile
  Push $R0
  Push $R1
  Push $R2
  Push $R3
 
  !define Index 'Line${__LINE__}'
 
  SetOutPath $FONT_DIR
  IfFileExists "$FONT_DIR\${FontFile}" ${Index} "${Index}-New"
 
  !ifdef FontBackup
    "${Index}-New:"
    ;Implementation of Font Backup Store
      WriteRegStr HKLM "${FontBackup}" "${FontFile}" "OK"
      File '${FontFile}'
      goto ${Index}
  !else
    "${Index}-New:"
      File '${FontFile}'
      goto ${Index}
  !endif
 
${Index}:
  ClearErrors
  ReadRegStr $R0 HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion" "CurrentVersion"
  IfErrors "${Index}-9x" "${Index}-NT"
 
"${Index}-NT:"
  StrCpy $R1 "Software\Microsoft\Windows NT\CurrentVersion\Fonts"
  goto "${Index}-GO"
 
"${Index}-9x:"
  StrCpy $R1 "Software\Microsoft\Windows\CurrentVersion\Fonts"
  goto "${Index}-GO"
 
"${Index}-GO:"
  ClearErrors
  !insertmacro FontName "$FONT_DIR\${FontFile}"
  pop $R2
  IfErrors 0 "${Index}-Add"
    MessageBox MB_OK "$R2"
    goto "${Index}-End"
 
"${Index}-Add:"
  StrCpy $R2 "$R2 (TrueType)"
  ClearErrors
  ReadRegStr $R0 HKLM "$R1" "$R2"
  IfErrors 0 "${Index}-End"
    System::Call "GDI32::AddFontResourceA(t) i ('${FontFile}') .s"
    WriteRegStr HKLM "$R1" "$R2" "${FontFile}"
    goto "${Index}-End"
 
"${Index}-End:"
 
  !undef Index
 
  pop $R3
  pop $R2
  pop $R1
  pop $R0
!macroend
 
!macro InstallFON FontFile FontName
  Push $R0
  Push $R1
 
  !define Index 'Line${__LINE__}'
 
  SetOutPath $FONT_DIR
  IfFileExists "$FONT_DIR\${FontFile}" ${Index} "${Index}-New"
 
  !ifdef FontBackup
    "${Index}-New:"
    ;Implementation of Font Backup Store
      WriteRegStr HKLM "${FontBackup}" "${FontFile}" "OK"
      File '${FontFile}'
      goto ${Index}
  !else
    "${Index}-New:"
      File '${FontFile}'
      goto ${Index}
  !endif
 
${Index}:
  ClearErrors
  ReadRegStr $R0 HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion" "CurrentVersion"
  IfErrors "${Index}-9x" "${Index}-NT"
 
"${Index}-NT:"
  StrCpy $R1 "Software\Microsoft\Windows NT\CurrentVersion\Fonts"
  goto "${Index}-GO"
 
"${Index}-9x:"
  StrCpy $R1 "Software\Microsoft\Windows\CurrentVersion\Fonts"
  goto "${Index}-GO"
 
"${Index}-GO:"
  ClearErrors
  ReadRegStr $R0 HKLM "$R1" "${FontName}"
  IfErrors 0 "${Index}-End"
    System::Call "GDI32::AddFontResourceA(t) i ('${FontFile}') .s"
    WriteRegStr HKLM "$R1" "${FontName}" "${FontFile}"
    goto "${Index}-End"
 
"${Index}-End:"
 
  !undef Index
 
  pop $R1
  pop $R0
!macroend
 
; Uninstaller entries
 
!macro RemoveTTF FontFile
Push $R0
Push $R1
Push $R2
Push $R3
Push $R4
 
  !define Index 'Line${__LINE__}'
 
  IfFileExists "$FONT_DIR\${FontFile}" ${Index} "${Index}-End"
 
${Index}:
  ClearErrors
  ReadRegStr $R0 HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion" "CurrentVersion"
  IfErrors "${Index}-9x" "${Index}-NT"
 
"${Index}-NT:"
  StrCpy $R1 "Software\Microsoft\Windows NT\CurrentVersion\Fonts"
  goto "${Index}-GO"
 
"${Index}-9x:"
  StrCpy $R1 "Software\Microsoft\Windows\CurrentVersion\Fonts"
  goto "${Index}-GO"
 
  !ifdef FontBackup
  "${Index}-GO:"
  ;Implementation of Font Backup Store
    StrCpy $R2 ''
    ReadRegStr $R2 HKLM "${FontBackup}" "${FontFile}"
    StrCmp $R2 'OK' 0 "${Index}-Skip"
 
    ClearErrors
    !insertmacro FontName "$FONT_DIR\${FontFile}"
    pop $R2
    IfErrors 0 "${Index}-Remove"
    MessageBox MB_OK "$R2"
    goto "${Index}-End"    
 
  "${Index}-Remove:"
    StrCpy $R2 "$R2 (TrueType)"
    System::Call "GDI32::RemoveFontResourceA(t) i ('${FontFile}') .s"
    DeleteRegValue HKLM "$R1" "$R2"
    DeleteRegValue HKLM "${FontBackup}" "${FontFile}"
    EnumRegValue $R4 HKLM "${FontBackup}" 0
    IfErrors 0 "${Index}-NoError"
      MessageBox MB_OK "FONT (${FontFile}) Removal.$\r$\n(Registry Key Error: $R4)$\r$\nRestart computer and try again. If problem persists contact your supplier."
      Abort "EnumRegValue Error: ${FontFile} triggered error in EnumRegValue for Key $R4."
  "${Index}-NoError:"
    StrCmp $R4 "" 0 "${Index}-NotEmpty"
      DeleteRegKey HKLM "${FontBackup}" ; This will delete the key if there are no more fonts...
  "${Index}-NotEmpty:"
    Delete /REBOOTOK "$FONT_DIR\${FontFile}"
    goto "${Index}-End"
  "${Index}-Skip:"
    goto "${Index}-End"
  !else
  "${Index}-GO:"
 
    ClearErrors
    !insertmacro FontName "$FONT_DIR\${FontFile}"
    pop $R2
    IfErrors 0 "${Index}-Remove"
    MessageBox MB_OK "$R2"
    goto "${Index}-End"
 
  "${Index}-Remove:"
    StrCpy $R2 "$R2 (TrueType)"
    System::Call "GDI32::RemoveFontResourceA(t) i ('${FontFile}') .s"
    DeleteRegValue HKLM "$R1" "$R2"
    delete /REBOOTOK "$FONT_DIR\${FontFile}"
    goto "${Index}-End"
  !endif
 
"${Index}-End:"
 
!undef Index
 
pop $R4
pop $R3
pop $R2
pop $R1
pop $R0
!macroend
 
!macro RemoveFON FontFile FontName
Push $R0
Push $R1
Push $R2
Push $R3
Push $R4
 
  !define Index 'Line${__LINE__}'
 
  IfFileExists "$FONT_DIR\${FontFile}" ${Index} "${Index}-End"
 
${Index}:
  ClearErrors
  ReadRegStr $R0 HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion" "CurrentVersion"
  IfErrors "${Index}-9x" "${Index}-NT"
 
"${Index}-NT:"
  StrCpy $R1 "Software\Microsoft\Windows NT\CurrentVersion\Fonts"
  goto "${Index}-GO"
 
"${Index}-9x:"
  StrCpy $R1 "Software\Microsoft\Windows\CurrentVersion\Fonts"
  goto "${Index}-GO"
 
  !ifdef FontBackup
  "${Index}-GO:"
  ;Implementation of Font Backup Store
    StrCpy $R2 ''
    ReadRegStr $R2 HKLM "${FontBackup}" "${FontFile}"
    StrCmp $R2 'OK' "${Index}-Remove" "${Index}-Skip"
 
  "${Index}-Remove:"
    System::Call "GDI32::RemoveFontResourceA(t) i ('${FontFile}') .s"
    DeleteRegValue HKLM "$R1" "${FontName}"
    DeleteRegValue HKLM "${FontBackup}" "${FontFile}"
    EnumRegValue $R4 HKLM "${FontBackup}" 0
    IfErrors 0 "${Index}-NoError"
      MessageBox MB_OK "FONT (${FontFile}) Removal.$\r$\n(Registry Key Error: $R4)$\r$\nRestart computer and try again. If problem persists contact your supplier."
      Abort "EnumRegValue Error: ${FontFile} triggered error in EnumRegValue for Key $R4."
  "${Index}-NoError:"
    StrCmp $R4 "" 0 "${Index}-NotEmpty"
      DeleteRegKey HKLM "${FontBackup}" ; This will delete the key if there are no more fonts...
  "${Index}-NotEmpty:"
    Delete /REBOOTOK "$FONT_DIR\${FontFile}"
    goto "${Index}-End"
  "${Index}-Skip:"
    goto "${Index}-End"
  !else
  "${Index}-GO:"
    System::Call "GDI32::RemoveFontResourceA(t) i ('${FontFile}') .s"
    DeleteRegValue HKLM "$R1" "${FontName}"
    delete /REBOOTOK "$FONT_DIR\${FontFile}"
    goto "${Index}-End"
  !endif
 
"${Index}-End:"
 
!undef Index
 
pop $R4
pop $R3
pop $R2
pop $R1
pop $R0
!macroend

After including that file in your script you should make sure that the '$FONT_DIR' variable is set to the right fonts directory of the target machine and make sure that you define the FontBackup variable to point to the location were you would like to store the names of the fonts that were not present on the users machine when the installer was executed and thus should be safe to remove when uninstalling provided that no newer program are using this font. Also of note is the last command in the fonts Section, it enables Windows and other programs to refresh their fonts lists without the need to restart the computer. Fonts will most likely not be completely removed until the PC is restarted as fonts are only removed if no programs are using the fonts list. Please note that FontFile parameter should be just the font filename, without a preceding path. If the fonts are not stored in the same location as the script you should use the '!cd' command to change the compiler path to the location of the fonts before calling the font macros.

Calling the RemoveTTF and RemoveFON macros is identical to their installation variants. You should note that you must also include the FontName.nsh file available with the FontName plugin. 

!include FontRegAdv.nsh
!include FontName.nsh
 
!define FontBackup Reg\key\To\Backup\Fonts\entries\To'
 
[...]
 
Section "Fonts"
; Alternate for older versions of NSIS: pre NSIS v2.0rc1
;  push $1
;  System::Call "Shell32::SHGetSpecialFolderLocation(i $HWNDPARENT, i ${CSIDL_FONTS}|${CSIDL_FLAG_CREATE}, *i .r0)"
;  System::Call "Shell32::SHGetPathFromIDList(i r0, t .r1)"
;  System::Call 'shell32::SHGetMalloc(*i . r2)' ; IMalloc
;  System::Call '$2->5(i r0)' ; ->Free
;  System::Call '$2->2()' ; ->Release
;  StrCpy $FONT_DIR $1
;  pop $1
 
  StrCpy $FONT_DIR $FONTS
 
  !insertmacro InstallTTF 'ARLRDBD.TTF'
  !insertmacro InstallTTF 'LUCON.TTF'
  !insertmacro InstallTTF 'OCRAEXT.TTF'
  !insertmacro InstallFON 'ROMAN.FON'   'Roman (All res)'
  !insertmacro InstallFON 'SMALLE.FON'  'Small Fonts (VGA res)'
 
  SendMessage ${HWND_BROADCAST} ${WM_FONTCHANGE} 0 0 /TIMEOUT=5000
SectionEnd
 
Section "un.Fonts"
; Alternate for older versions of NSIS: pre NSIS v2.0rc1
;  push $1
;  System::Call "Shell32::SHGetSpecialFolderLocation(i $HWNDPARENT, i ${CSIDL_FONTS}|${CSIDL_FLAG_CREATE}, *i .r0)"
;  System::Call "Shell32::SHGetPathFromIDList(i r0, t .r1)"
;  System::Call 'shell32::SHGetMalloc(*i . r2)' ; IMalloc
;  System::Call '$2->5(i r0)' ; ->Free
;  System::Call '$2->2()' ; ->Release
;  StrCpy $FONT_DIR $1
;  pop $1
 
  StrCpy $FONT_DIR $FONTS
 
  !insertmacro RemoveTTF 'ARLRDBD.TTF'
  !insertmacro RemoveTTF 'LUCON.TTF'
  !insertmacro RemoveTTF 'OCRAEXT.TTF'
  !insertmacro RemoveFON 'ROMAN.FON'   'Roman (All res)'
  !insertmacro RemoveFON 'SMALLE.FON'  'Small Fonts (VGA res)'
 
  SendMessage ${HWND_BROADCAST} ${WM_FONTCHANGE} 0 0 /TIMEOUT=5000
SectionEnd

A few notes about using InstallFON macro: You should copy the 'FontName' out of the registry of the Source machine as the fonts might not work if the wrong name or type is specified. The location of the fonts folder can be attained in a number of different ways, reading a registry key from the target machine or the way shown above, obtained from an example by Joel. Note that this way uses the system plugin and if the size of your installer is a *very* big issue reading the registry might save a few bytes in the final installer size.

Version History

[Update 2005-01-18]
Fixed problem with FON installation as reported by Francois Gelinas
[Update 2004-01-29]
Updated to use FontName v0.6
[Update 2003-12-29]
Added definition of CSIDL_FLAG_CREATE flag.
[Update 2003-12-28]
Added a note about $FONTS variable first included in NSIS v2.0rc1
[Update 2003-12-23]
Fixed some typos in the documentation and notes.
[Update 2003-12-07]
Fixed problem with remove macros removing only the first font, thanks to lewellyn for bug report and solution.
[Update 2003-12-05]
Added a note about the font filenames and macro usage if fonts not in the same folder as the script.
[Update 2003-11-28]
Fixed problem with TTF font installation on Windows 9x with help from brainsucker and kichik. Added error reporting functionality for the FontName plugin.
[Update 2003-11-21]
Fixed macro name mismatch.

Vytautas

Page author: Vytautas

Retrieved from "https://nsis.sourceforge.io/mediawiki/index.php?title=Advanced_Font_Installation&oldid=1785"