FileOpen2

Author: Lloigor (talk, contrib)

Description

Open files with control over access, share and create modes with intuitive parameters.

Example

;; Open file with RW access, ReadOnly sharing, and if it does not exists, Creates it. $1 gets the file handle.
${FileOpen2} $1 "$SomeFile" "w" "r" "c"

Function

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Easily open files with more options than FileOpen. Use lowercase
;;   P1 :out: Handle
;;   P2 :in:  File name
;;   P3 :in:  Access Mode (default=r)
;;            'r' : Read
;;            'w' : Read+Write
;;   P4 :in:  Share mode (default=w)
;;            'l' : None              (full lock)
;;            'r' : Read              (no delete, no write)
;;            'w' : Read+Write        (no delete)
;;            'a' : Read+Write+Delete (full share)
;;   P5 :in:  Create mode (default=o)
;;            'o' : Open existing only
;;            'c' : Create if not exist
;;            'v' : Create and Overwrite
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
!define FileOpen2 "!insertmacro _FileOpen2"
!macro _FileOpen2 _Handle_ _File_ _Access_ _Share_ _Create_
   Push "${_Create_}"
   Push "${_Share_}"
   Push "${_Access_}"
   Push "${_File_}"
   Call FileOpen2
   Pop ${_Handle_}
!macroend
 
Function FileOpen2  ;; File, Access, Share, Create
   Exch $0  ;; File
   Exch
   Exch $1  ;; Access
   Exch 2
   Exch $2  ;; Share / Return value
   Exch 3
   Exch $3  ;; Create
 
   StrCmpS "w" $1 0 +3
      StrCpy $1 0xC0000000  ;; GENERIC_READ | GENERIC_WRITE
      Goto +2
;- else: "r", "", or anything else
      StrCpy $1 0x80000000  ;; GENERIC_READ
 
   StrCmpS "l" $2 0 +3
      StrCpy $2 0           ;; FILE_SHARE_NONE
      Goto +8
   StrCmpS "r" $2 0 +3
      StrCpy $2 1           ;; FILE_SHARE_READ
      Goto +5
   StrCmpS "a" $2 0 +3
      StrCpy $2 7           ;; FILE_SHARE_READ | FILE_SHARE_WRITE | FILE_SHARE_DELETE
;- else: "w", "", or anything else
      StrCpy $2 3           ;; FILE_SHARE_READ | FILE_SHARE_WRITE
      Goto +2
 
   StrCmpS "v" $3 0 +3
      StrCpy $3 2           ;; CREATE_ALWAYS
      Goto +5
   StrCmpS "c" $3 0 +3
      StrCpy $3 4           ;; OPEN_ALWAYS
      Goto +2
;- else: "o", "", or anything else
      StrCpy $3 3           ;; OPEN_EXISTING
 
   System::Call 'Kernel32::CreateFile(t, i, i, i, i, i, i) i (r0, r1, r2, 0, r3, 0x80, 0) .r2'  ;; Open/Create file
 
   Pop $3
   Pop $0
   Pop $1
   Exch $2  ;; Return Handle
FunctionEnd