Install PostScript Fonts

Author: Jan (talk, contrib)

Description

This script is based on the Advanced Font Installation script, it can be used to install a PostScript/Type 1 font. It requires the Registry Plugin by Instructor

Function

!ifndef GetBaseName
	!include FileFunc.nsh
	!insertmacro GetBaseName
!endif
 
; requires the Registry plugin by Instructor
!macro registry::Write _PATH _VALUE _STRING _TYPE _ERR
	registry::_Write /NOUNLOAD `${_PATH}` `${_VALUE}` `${_STRING}` `${_TYPE}`
	Pop ${_ERR}
!macroend
!define registry::Write `!insertmacro registry::Write`
 
 
; !insertmacro InstallPostScript "C:\PathTo\MyFontB.pfm" "My Font Bold"
!macro InstallPostScript FontPath FontName
  Push $0
  Push $R0
  Push $R1
  Push $R2
 
  !define Index 'Line${__LINE__}'
 
  ${GetBaseName} "${FontPath}" $0
  !define FontBase $0
 
  SetOutPath $FONTS
  IfFileExists "$FONTS\${FontBase}.pfm" ${Index} "${Index}-New"
 
"${Index}-New:"
  File '${FontPath}'
  goto ${Index}
 
${Index}:
  ClearErrors
  ReadRegStr $R0 HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion" "CurrentVersion"
  IfErrors "${Index}-Error" "${Index}-GO"
 
"${Index}-Error:"
  MessageBox MB_OK|MB_ICONEXCLAMATION "PostScript fonts can only be installed in Windows 2000 or later!"
  goto "${Index}-End"
 
"${Index}-GO:"
    ClearErrors
    ${registry::Write} "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Type 1 Installer\Type 1 Fonts" "${FontName}" "T ${FontBase}.pfm ${FontBase}.pfb" "REG_MULTI_SZ" $R0
    System::Call "GDI32::AddFontResourceA(t) i ('${FontBase}.pfm|${FontBase}.pfb') .s"
    goto "${Index}-End"
 
"${Index}-End:"
 
  !undef Index
  !undef FontBase 
 
  Pop $R2
  Pop $R1
  Pop $R0
  Pop $0
!macroend

Changelog

[2008-07-24] first public release

Additional Resources

-t1tools is a collection of programs and batch files useful for handling type 1 fonts on MSDOS and Unix systems.
-PostScript fonts at Wikipedia