Register Fonts

Description

A more advanced version of font registration can be found here. Although this version might be more appropriate if you do not need the advanced functionality.

This page has been redesigned to include the functionality of the FontName plugin. This will allow you to register TTF fonts without the need to supply the font's registry name. The second macro is designed to register FON fonts and still requires the input of the font's name.

These macros have been designed to work with NSIS 2.0b4 (CVS), although it could possibly be modified to work with earlier versions of NSIS.

Please note that uninstalling fonts is generally not a good idea since other programs might depend on them. Exceptions would be custom created fonts which would only be used by your program or when installing a *huge* amount of fonts.

The Script

Save this script as a NSIS Include file in the Include directory of NSIS so that then you can easily get font registration functionality in any script by simply including this file. (Suggested file name: FontReg.nsh)

var FONT_DIR
 
!ifndef CSIDL_FONTS
  !define CSIDL_FONTS '0x14' ;Fonts directory path constant
!endif
!ifndef CSIDL_FLAG_CREATE
  !define CSIDL_FLAG_CREATE 0x8000
!endif
 
!macro InstallTTFFont FontFile
  Push $R0
  Push $R1
  Push $R2
 
  !define Index 'Line${__LINE__}'
 
  SetOutPath $FONT_DIR
  IfFileExists "$FONT_DIR\${FontFile}" ${Index}
    File '${FontFile}'
 
${Index}:
  ReadRegStr $R0 HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion" "CurrentVersion"
  IfErrors "${Index}-9x" "${Index}-NT"
 
"${Index}-NT:"
  StrCpy $R1 "Software\Microsoft\Windows NT\CurrentVersion\Fonts"
  goto "${Index}-GO"
 
"${Index}-9x:"
  StrCpy $R1 "Software\Microsoft\Windows\CurrentVersion\Fonts"
  goto "${Index}-GO"
 
"${Index}-GO:"
  ClearErrors
  !insertmacro FontName "$FONT_DIR\${FontFile}"
  pop $R2
  IfErrors 0 "${Index}-Add"
    MessageBox MB_OK "$R2"
    goto "${Index}-End"
 
"${Index}-Add:"
  StrCpy $R2 "$R2 (TrueType)"
  ClearErrors
  ReadRegStr $R0 HKLM "$R1" "$R2"
  IfErrors 0 "${Index}-End"
    System::Call "GDI32::AddFontResourceA(t) i ('${FontFile}') .s"
    WriteRegStr HKLM "$R1" "$R2" "${FontFile}"
    goto "${Index}-End"
 
"${Index}-End:"
 
  !undef Index
 
  pop $R2
  pop $R1
  pop $R0
!macroend
 
!macro InstallFONFont FontFile FontName
  Push $R0
  Push $R1
 
  !define Index 'Line${__LINE__}'
 
  SetOutPath $FONT_DIR
  IfFileExists "$FONT_DIR\${FontFile}" ${Index}
    File '${FontFile}'
 
${Index}:
  ClearErrors
  ReadRegStr $R0 HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion" "CurrentVersion"
  IfErrors "${Index}-9x" "${Index}-NT"
 
"${Index}-NT:"
  StrCpy $R1 "Software\Microsoft\Windows NT\CurrentVersion\Fonts"
  goto "${Index}-GO"
 
"${Index}-9x:"
  StrCpy $R1 "Software\Microsoft\Windows\CurrentVersion\Fonts"
  goto "${Index}-GO"
 
"${Index}-GO:"
  ClearErrors
  ReadRegStr $R0 HKLM "$R1" "${FontName}"
  IfErrors 0 "${Index}-End"
    System::Call "GDI32::AddFontResourceA(t) i ('${FontFile}') .s"
    WriteRegStr HKLM "$R1" "${FontName}" "${FontFile}"
    goto "${Index}-End"
 
"${Index}-End:"
 
  !undef Index
 
  pop $R1
  pop $R0
!macroend
 
; Uninstaller entries
 
!macro RemoveTTFFont FontFile
  Push $R0
  Push $R1
  Push $R2
 
  !define Index 'Line${__LINE__}'
 
  SetOutPath $FONT_DIR
  IfFileExists "$FONT_DIR\${FontFile}" ${Index} "${Index}-End"
 
${Index}:
  ReadRegStr $R0 HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion" "CurrentVersion"
  IfErrors "${Index}-9x" "${Index}-NT"
 
"${Index}-NT:"
  StrCpy $R1 "Software\Microsoft\Windows NT\CurrentVersion\Fonts"
  goto "${Index}-GO"
 
"${Index}-9x:"
  StrCpy $R1 "Software\Microsoft\Windows\CurrentVersion\Fonts"
  goto "${Index}-GO"
 
"${Index}-GO:"
  ClearErrors
  !insertmacro FontName "$FONT_DIR\${FontFile}"
  pop $R2
  IfErrors 0 "${Index}-Remove"
    MessageBox MB_OK "$R2"
    goto "${Index}-End"
 
"${Index}-Remove:"
  StrCpy $R2 "$R2 (TrueType)"
  System::Call "GDI32::RemoveFontResourceA(t) i ('${FontFile}') .s"
  DeleteRegValue HKLM "$R1" "$R2"
  delete /REBOOTOK "$FONT_DIR\${FontFile}"
  goto "${Index}-End"
 
"${Index}-End:"
 
  !undef Index
 
  pop $R2
  pop $R1
  pop $R0
!macroend
 
!macro RemoveFONFont FontFile FontName
  Push $R0
  Push $R1
 
  !define Index 'Line${__LINE__}'
 
  SetOutPath $FONT_DIR
  IfFileExists "$FONT_DIR\${FontFile}" "${Index}" "${Index}-End"
 
${Index}:
  ReadRegStr $R0 HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion" "CurrentVersion"
  IfErrors "${Index}-9x" "${Index}-NT"
 
"${Index}-NT:"
  StrCpy $R1 "Software\Microsoft\Windows NT\CurrentVersion\Fonts"
  goto "${Index}-GO"
 
"${Index}-9x:"
  StrCpy $R1 "Software\Microsoft\Windows\CurrentVersion\Fonts"
  goto "${Index}-GO"
 
"${Index}-GO:"
  System::Call "GDI32::RemoveFontResourceA(t) i ('${FontFile}') .s"
  DeleteRegValue HKLM "$R1" "${FontName}"
  delete /REBOOTOK "$FONT_DIR\${FontFile}"
  goto "${Index}-End"
 
"${Index}-End:"
 
  !undef Index
 
  pop $R1
  pop $R0
!macroend

After including that file in your script you should make sure that the '$FONT_DIR' variable is set to the right fonts directory of the target machine. Also of note is the last command in the fonts Section, it enables Windows and other programs to refresh their fonts lists without the need to restart the computer. You MUST also include the FontName.nsh file from the FontName plugin.

Calling the RemoveTTFFont and RemoveFONFont macros is identical to their installation variants.

!include FontReg.nsh
!include FontName.nsh
 
[...]
 
Section "Fonts"
; Alternate for older versions of NSIS: pre NSIS v2.0rc1
;  push $1
;  System::Call "Shell32::SHGetSpecialFolderLocation(i $HWNDPARENT, i ${CSIDL_FONTS}|${CSIDL_FLAG_CREATE}, *i .r0)"
;  System::Call "Shell32::SHGetPathFromIDList(i r0, t .r1)"
;  System::Call 'shell32::SHGetMalloc(*i . r2)' ; IMalloc
;  System::Call '$2->5(i r0)' ; ->Free
;  System::Call '$2->2()' ; ->Release
;  StrCpy $FONT_DIR $1
;  pop $1
 
  StrCpy $FONT_DIR $FONTS
 
  !insertmacro InstallTTFFont 'ARLRDBD.TTF'
  !insertmacro InstallTTFFont 'LUCON.TTF'
  !insertmacro InstallTTFFont 'OCRAEXT.TTF'
  !insertmacro InstallFONFont 'ROMAN.FON'   'Roman (All res)'
  !insertmacro InstallFONFont 'SMALLE.FON'  'Small Fonts (VGA res)'
 
  SendMessage ${HWND_BROADCAST} ${WM_FONTCHANGE} 0 0 /TIMEOUT=5000
SectionEnd

A few notes about using InstallFONFont macro: You should copy the 'FontName' out of the registry of the Source machine as the fonts might not work if the wrong name or type is specified.

The location of the fonts folder can be attained in a number of different ways, reading a registry key from the target machine or the way shown above, obtained from an example by Joel. Note that this way uses the system plugin and if the size of your installer is a *very* big issue reading the registry might save a few bytes in the final installer size.

Version History

[Update 2005-01-18]

Fixed problem with FON installation as reported by Francois Gelinas

[Update 2004-01-29]

Updated to use FontName v0.6.

[Update 2003-12-29]

Fixed Macro naming errors, added CSIDL_FLAG_CREATE flag definition.

[Update 2003-12-28]

Added a note about $FONTS variable first included in NSIS v2.0rc1

[Update 2003-11-28]

Fixed problem with TTF font installation on Windows 9x with help from brainsucker and kichik. Added error reporting functionality for the FontName plugin.

[Update 2003-11-18]

Added Remove functionality for the uninstaller as requested by lewellyn.

[Update 2003-11-17]

Added TIMEOUT to the SendMessage command to prevent installer from freezing as suggested by kichik.

[Update 2003-11-12]

Changed the macros so that they no longer require a unique index, with help from Joost Verburg.

[Update 2003-11-11]

Added support for the 'TTF Font Name' plugin. Added macro for FON font installation.

Credits

Vytautas

PS. Created with a lot of help from members of the NSIS Forum.

Page author: Vytautas