CmdExec

Author: Lloigor (talk, contrib)

Description

Use cmd.exe to execute a command and its parameters, with working dir, optional dospause, stayinprompt and execwait.

Example

${CmdPause} `$ParentFolder` `"d:\tools\free_upx\upx.exe" -v --brute $FileNames`

Macro

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;  Execute a command with cmd.exe
;;  P1 :in: Working directory, ignored if "" ($OutDir is used)
;;  P2 :in: Command and parameters
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
!define CmdExec "!insertmacro _CmdExec 0"
!define CmdPause "!insertmacro _CmdExec 1"
!define CmdWait "!insertmacro _CmdExec 2"
!define CmdPauseWait "!insertmacro _CmdExec 3"
!define CmdStay "!insertmacro _CmdExec 4"       ; Stay in command box after execution
!define CmdStayWait  "!insertmacro _CmdExec 5"  ; Stay in command box after execution, and wait for it to exit
!macro _CmdExec _Mode_ _WorkDir_ _CommandAndParams_  ; Mode: 0=nopause/nowait, 1=dospause, 2=execwait, 3=dospause+execwait
   Push $R0
   ExpandEnvStrings $R0 '%COMSPEC%'
   StrCmp "${_WorkDir_}" "" +3
      Push $OutDir
      SetOutPath "${_WorkDir_}"
   !if '${_Mode_}' == '1'
      Exec `"$R0" /c "${_CommandAndParams_}" & echo. & echo. & pause`
   !else if '${_Mode_}' == '2'
      ExecWait `"$R0" /c "${_CommandAndParams_}"`
   !else if '${_Mode_}' == '3'
      ExecWait `"$R0" /c "${_CommandAndParams_}" & echo. & echo. & pause`
   !else if '${_Mode_}' == '4'
      Exec `"$R0" /k "${_CommandAndParams_}"`
   !else if '${_Mode_}' == '5'
      ExecWait `"$R0" /k "${_CommandAndParams_}"`
   !else
      Exec `"$R0" /c "${_CommandAndParams_}"`
   !endif
   StrCmp "${_WorkDir_}" "" +3
      Pop $R0
      SetOutPath "$R0"
   Pop $R0
!macroend