CmdExec

Author: Lloigor (talk, contrib)

Description

Use cmd.exe to execute a command and its parameters, with working dir, optional dospause, stayinprompt and execwait.

Example

${CmdPause} `$ParentFolder` `"d:\tools\free_upx\upx.exe" -v --brute $FileNames`

Macro

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; 
;;  Execute a command with cmd.exe 
;;  P1 :in: Working directory (""=$outdir) 
;;  P2 :in: Command and parameters 
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; 
!define Cmd "!insertmacro _CmdExec 0"         ; nopause/nowait
!define CmdWait "!insertmacro _CmdExec 1"      ; execwait
!define CmdPause "!insertmacro _CmdExec 2"     ; dospause
!define CmdPauseWait "!insertmacro _CmdExec 3" ; dospause+execwait
!define CmdStay "!insertmacro _CmdExec 4"       ; stay in command prompt
!define CmdStayWait  "!insertmacro _CmdExec 5"  ; stay+execwait
;;
!macro _CmdExec _Mode_ _WorkDir_ _CommandAndParams_
   StrCmp "${_WorkDir_}" "" +3 
      Push $OutDir 
      SetOutPath "${_WorkDir_}" 
   !if '${_Mode_}' == '1' 
      ExecWait `"$SYSDIR\cmd.exe" /c "${_CommandAndParams_}"` 
   !else if '${_Mode_}' == '2' 
      Exec `"$SYSDIR\cmd.exe" /c "${_CommandAndParams_}" & echo. & echo. & pause` 
   !else if '${_Mode_}' == '3' 
      ExecWait `"$SYSDIR\cmd.exe" /c "${_CommandAndParams_}" & echo. & echo. & pause` 
   !else if '${_Mode_}' == '4'
      Exec `"$SYSDIR\cmd.exe" /k "${_CommandAndParams_}"`
   !else if '${_Mode_}' == '5'
      ExecWait `"$SYSDIR\cmd.exe" /k "${_CommandAndParams_}"`
   !else 
      Exec `"$SYSDIR\cmd.exe" /c "${_CommandAndParams_}"` 
   !endif 
   StrCmp "${_WorkDir_}" "" +4 
      Exch $R0 
      SetOutPath "$R0" 
      Pop $R0 
!macroend